OriginAdapter

{{
  "language": "Solidity",
  "sources": {
    "src/strategies/OriginAdapter.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

import "./BaseAdapter.sol";
import {IERC20} from "lib/forge-std/src/interfaces/IERC20.sol";
import {IERC20 as IERC20OZ} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";

interface IOUSDVault {
    function mint(address asset, uint256 amount, uint256 minOusdAmount) external returns (uint256);
    function redeem(uint256 amount, uint256[] calldata minAmounts) external returns (uint256[] memory);
    function rebasePerSecondTarget() external view returns (uint64);
    function getAllAssets() external view returns (address[] memory);
}

interface IOUSD is IERC20 {
    function rebaseOptIn() external;
    function totalSupply() external view returns (uint256);
    function nonRebasingSupply() external view returns (uint256);
}

interface IUniswapV2Router {
    function getAmountsOut(uint256 amountIn, address[] calldata path) external view returns (uint256[] memory amounts);
    function swapExactTokensForTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);
}

/**
 * @title OriginAdapter
 * @notice Adapter for OUSD (Origin Dollar) strategy
 * @dev Deposit USDC → Vault → OUSD, redeem back to USDC when withdrawing
 */
contract OriginAdapter is BaseAdapter, ReentrancyGuard {
    using SafeERC20 for IERC20OZ;

    IERC20OZ public immutable USDC;
    IOUSD public immutable OUSD;
    IOUSDVault public immutable vault;
    IERC20OZ public immutable USDT;
    IERC20OZ public immutable USDS;
    IUniswapV2Router public immutable router;

    uint256 private constant WAD = 1e18;
    uint256 private constant SECONDS_PER_YEAR = 365 days;
    uint256 private constant BPS_DENOM = 10_000;
    uint256 private constant FEE_BPS = 25; // 0.25% fee on yield (Origin default)
    uint256 public slippageBps = 9_950;    // 0.5% tolerance
    mapping(address => uint256) public userSlippageBps;

    event Deposited(address indexed user, uint256 usdcIn, uint256 sharesMinted);
    event Withdrawn(address indexed user, uint256 sharesBurned, uint256 usdcOut);
    event SwapFailed(address token, uint256 amount);

    constructor(
        IERC20OZ _usdc,
        IOUSD _ousd,
        IOUSDVault _vault,
        address _usdt,
        address _usds,
        IUniswapV2Router _router
    ) {
        USDC = _usdc;
        OUSD = _ousd;
        vault = _vault;
        USDT = IERC20OZ(_usdt);
        USDS = IERC20OZ(_usds);
        router = _router;

        // Approvals (pakai forceApprove karena OZ v5.4.0)
        USDC.forceApprove(address(vault), type(uint256).max);
        IERC20OZ(address(OUSD)).forceApprove(address(vault), type(uint256).max);

        try OUSD.rebaseOptIn() {
        } catch Error(string memory reason) {
            revert(string(abi.encodePacked("Rebase opt-in failed: ", reason)));
        } catch {
            revert("Rebase opt-in failed: unknown error");
        }
    }

    function getQuote(address tokenIn, address tokenOut, uint256 amountIn) public view returns (uint256) {
        address[] memory path = new address[](2);
        path[0] = tokenIn;
        path[1] = tokenOut;

        uint256[] memory amountsOut = router.getAmountsOut(amountIn, path);
        return amountsOut[1];
    }


    // ===== Swap To USDC =====
    function _swapExactTokens(
        address tokenIn,
        address tokenOut,
        uint256 amountIn,
        uint256 minOut
    ) internal returns (uint256 outAmount) {
        address[] memory path = new address[](2);
        path[0] = tokenIn;
        path[1] = tokenOut;

        IERC20OZ(tokenIn).forceApprove(address(router), amountIn);

        // Add deadline parameter
        uint256 deadline = block.timestamp + 300; // 5 minutes

        uint256[] memory amounts = router.swapExactTokensForTokens(
            amountIn,
            minOut,              
            path,
            address(this),
            deadline
        );

        outAmount = amounts[1];
    }

    function setSlippageTolerance(uint256 _slippageBps) external {
        require(_slippageBps >= 9_000 && _slippageBps <= 10_000, "Invalid slippage");
        userSlippageBps[msg.sender] = _slippageBps;
    }

    // ===== Deposit USDC =====
    function deposit(uint256 amount) external override nonReentrant returns (uint256 sharesOut) {
        require(amount > 0, "amount=0");

        USDC.safeTransferFrom(msg.sender, address(this), amount);

        // Calculate minimum acceptable OUSD based on expected rate and slippage
        uint256 expectedOusd = amount * 1e12; // Convert to 18 decimals
        uint256 minOusd = (expectedOusd * 9950) / 10000; // 0.5% slippage tolerance

        uint256 totalValueBefore = getUsdcValue();
        uint256 ousdBefore = OUSD.balanceOf(address(this));
        uint256 ousdMinted = vault.mint(address(USDC), amount, minOusd);

        // Verify expected amount was minted
        uint256 ousdAfter = OUSD.balanceOf(address(this));
        require(ousdAfter >= ousdBefore + ousdMinted, "Mint verification failed");

        if (totalShares == 0) {
            sharesOut = amount;
        } else {
            require(ousdBefore > 0, "OriginAdapter: strategy value zero; deposits paused");
            // Use the deposited amount directly for fair share calculation
            sharesOut = (amount * totalShares) / totalValueBefore;
            require(sharesOut > 0, "OriginAdapter: deposit too small");
        }

        shares[msg.sender] += sharesOut;
        totalShares += sharesOut;

        emit Deposited(msg.sender, amount, sharesOut);
    }

    // ===== Withdraw USDC =====
    function withdraw(uint256 sharesToBurn) external override nonReentrant returns (uint256 withdrawnUsdc) {
        require(sharesToBurn > 0, "shares=0");

        uint256 totalUsdcValue = getUsdcValue();
        require(totalUsdcValue > 0, "empty");

        // ===== Pro-rata USDC value to withdraw =====
        uint256 usdcAmount = (sharesToBurn * totalUsdcValue) / totalShares;
        require(shares[msg.sender] >= sharesToBurn, "insufficient shares");

        shares[msg.sender] -= sharesToBurn;
        totalShares -= sharesToBurn;

        uint256 ousdAmount = usdcAmount * 1e12; // OUSD 18 decimals vs USDC 6

        // ===== User slippage =====
        uint256 slippage = userSlippageBps[msg.sender];
        if (slippage == 0) slippage = slippageBps;

        // ===== Build minAmounts dynamically =====
        // Assuming the vault exposes a list of assets (example: OUSD Vault has allAssets())
        address[] memory assets = vault.getAllAssets(); 
        require(assets.length <= 10, "Too many assets");

        uint256[] memory minAmounts = new uint256[](assets.length);

        for (uint256 i = 0; i < assets.length; i++) {
            if (assets[i] == address(USDC)) {
                // For USDC, expect at least the calculated amount minus slippage
                minAmounts[i] = (usdcAmount * slippage) / BPS_DENOM;
            } else {
                // For other assets, calculate expected amounts based on oracle prices
                // or use a conservative estimate
                try IERC20Metadata(assets[i]).decimals() returns (uint8 decimals) {
                    uint256 scaledAmount = usdcAmount * (10 ** decimals) / 1e6;
                    minAmounts[i] = (scaledAmount * slippage) / BPS_DENOM;
                } catch {
                    // Use a conservative default
                    minAmounts[i] = (usdcAmount * slippage * 95) / (BPS_DENOM * 100);
                }
            }
        }

        // ===== Redeem OUSD =====
        uint256 beforeUsdc = USDC.balanceOf(address(this));
        vault.redeem(ousdAmount, minAmounts);

        uint256 deadline = block.timestamp + 300; // 5 minutes
        // ===== Swap all non-USDC assets into USDC =====
        for (uint256 i = 0; i < assets.length; i++) {
            if (assets[i] != address(USDC)) {
                uint256 bal = IERC20OZ(assets[i]).balanceOf(address(this));
                if (bal > 0) {
                    // uint256 expectedOut = getQuote(assets[i], address(USDC), bal);
                    IERC20OZ(assets[i]).forceApprove(address(router), bal);
                    // build path
                    address[] memory path = new address[](2);
                    path[0] = assets[i];
                    path[1] = address(USDC);

                    // low-level call instead of try/catch
                    (bool success, ) = address(router).call(
                        abi.encodeWithSelector(
                            router.swapExactTokensForTokens.selector,
                            bal,
                            minAmounts[i],            
                            path,
                            address(this),
                            deadline
                        )
                    );

                    if (!success) {
                        // Try to transfer the token to the user
                        try IERC20OZ(assets[i]).transfer(msg.sender, bal) returns (bool transferred) {
                            require(transferred, "OriginAdapter: fallback transfer failed");
                            emit SwapFailed(assets[i], bal);
                        } catch {
                            // If transfer fails, revert the entire withdrawal
                            revert("OriginAdapter: unable to return non-USDC asset");
                        }
                    }
                }
            }
        }

        // ===== Final accounting =====
        withdrawnUsdc = USDC.balanceOf(address(this)) - beforeUsdc;
        require(withdrawnUsdc >= (usdcAmount * slippage) / BPS_DENOM, "slippage exceeded");

        USDC.safeTransfer(msg.sender, withdrawnUsdc);
        emit Withdrawn(msg.sender, sharesToBurn, withdrawnUsdc);
    }


    // ===== Views =====
    function balanceOf(address account) external view override returns (uint256) {
        if (totalShares == 0) return 0;
        return (shares[account] * getUsdcValue()) / totalShares;
    }

    function _getCurrentSharePrice() internal view override returns (uint256) {
        if (totalShares == 0) return WAD;
        return (getUsdcValue() * WAD) / totalShares;
    }

    function getUsdcValue() public view returns (uint256) {
        uint256 ousdBal = OUSD.balanceOf(address(this));
        // Round to nearest instead of always down
        uint256 remainder = ousdBal % 1e12;
        if (remainder >= 5e11) {
            return (ousdBal / 1e12) + 1;
        }
        return ousdBal / 1e12;
    }

    function getSharesOf(address account) external view returns (uint256) {
        return shares[account];
    }

    function getCurrentAPY() external view override returns (uint256 apyBps) {
        uint256 rps = vault.rebasePerSecondTarget();
        uint256 ts = OUSD.totalSupply();
        uint256 nrs = OUSD.nonRebasingSupply();

        uint256 rebasingSupply = ts > nrs ? ts - nrs : 0;
        if (rebasingSupply == 0) return 0;

        uint256 aprPre = (rps * SECONDS_PER_YEAR * WAD) / rebasingSupply;
        uint256 aprNet = (aprPre * (BPS_DENOM - FEE_BPS)) / BPS_DENOM;

        // Daily compound: (1 + apr/365)^365 - 1
        uint256 base = WAD + (aprNet / 365);
        uint256 acc = WAD;
        uint256 exp = 365;
        while (exp > 0) {
            if (exp & 1 == 1) acc = (acc * base) / WAD;
            base = (base * base) / WAD;
            exp >>= 1;
        }
        uint256 apy1e18 = acc - WAD;
        apyBps = (apy1e18 * 10_000) / WAD;
    }
}
"
    },
    "src/strategies/BaseAdapter.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

import "../interfaces/IStrategyAdapter.sol";

/**
 * @title BaseAdapter
 * @notice Abstract base contract for strategy adapters with APY tracking
 * @dev All strategy adapters should inherit from this contract
 */
abstract contract BaseAdapter is IStrategyAdapter {
    // APY tracking state
    uint256 internal lastSharePrice;
    uint256 internal lastUpdateTime;
    uint256 internal calculatedAPY;
    uint256 internal constant APY_PRECISION = 10000; // 100.00%
    uint256 internal constant MIN_UPDATE_INTERVAL = 1 hours;
    uint256 internal constant STALE_APY_THRESHOLD = 24 hours;
    
    // Share tracking
    mapping(address => uint256) internal shares;
    uint256 internal totalShares;
    
    // Events
    event MetricsUpdated(address indexed updater, uint256 newAPY, uint256 sharePrice);
    
    /**
     * @dev Must be implemented by each adapter to return current share price
     * @return Current price of 1 share in underlying assets (scaled by 1e18)
     */
    function _getCurrentSharePrice() internal view virtual returns (uint256);
    
    /**
     * @notice Update APY metrics based on share price changes
     * @dev Can be called by anyone after MIN_UPDATE_INTERVAL has passed
     */
    function updateMetrics() external virtual override {
        require(block.timestamp >= lastUpdateTime + MIN_UPDATE_INTERVAL, "BaseAdapter: Too soon to update");
        
        uint256 currentSharePrice = _getCurrentSharePrice();
        
        if (lastUpdateTime > 0 && lastSharePrice > 0 && currentSharePrice > lastSharePrice) {
            // Calculate time-weighted APY
            uint256 timeElapsed = block.timestamp - lastUpdateTime;
            
            // Calculate price change with precision
            // Formula: ((currentPrice - lastPrice) / lastPrice) * APY_PRECISION
            uint256 priceChangeRatio = ((currentSharePrice - lastSharePrice) * APY_PRECISION * 1e18) / lastSharePrice;
            
            // Annualize the return
            // Formula: (priceChangeRatio * SECONDS_PER_YEAR) / (timeElapsed * 1e18)
            calculatedAPY = (priceChangeRatio * 365 days) / (timeElapsed * 1e18);
        }
        
        lastSharePrice = currentSharePrice;
        lastUpdateTime = block.timestamp;
        
        emit MetricsUpdated(msg.sender, calculatedAPY, currentSharePrice);
    }
    
    /**
     * @notice Get the current APY
     * @dev Returns 0 if APY is stale (not updated in 24 hours)
     * @return Current APY in basis points
     */
    function getCurrentAPY() external view virtual override returns (uint256) {
        if (isAPYStale()) {
            return 0; // Return 0 for stale APY
        }
        return calculatedAPY;
    }
    
    /**
     * @notice Get the last time metrics were updated
     * @return Timestamp of last update
     */
    function getLastUpdateTime() external view override returns (uint256) {
        return lastUpdateTime;
    }
    
    /**
     * @notice Check if APY data is stale
     * @return True if last update was more than 24 hours ago
     */
    function isAPYStale() public view override returns (bool) {
        return block.timestamp > lastUpdateTime + STALE_APY_THRESHOLD;
    }
    
    /**
     * @dev Initialize metrics on deployment
     * Should be called in the constructor of inheriting contracts
     */
    function _initializeMetrics() internal {
        uint256 initialPrice = _getCurrentSharePrice();
        if (initialPrice > 0) {
            lastSharePrice = initialPrice;
            lastUpdateTime = block.timestamp;
        }
        calculatedAPY = 0; // Will be set on first update
    }
    
    /**
     * @notice Get shares held by an account
     * @param account Address to check
     * @return Number of shares
     */
    function sharesOf(address account) external view returns (uint256) {
        return shares[account];
    }
    
    /**
     * @notice Get total shares minted
     * @return Total number of shares
     */
    function getTotalShares() external view returns (uint256) {
        return totalShares;
    }
    
    /**
     * @notice Get current share price
     * @return Price of 1 share in underlying assets (scaled by 1e18)
     */
    function sharePrice() external view returns (uint256) {
        return _getCurrentSharePrice();
    }
    
    /**
     * @dev Modifier to update metrics if needed before user interactions
     */
    modifier updateMetricsModifier() {
        if (block.timestamp >= lastUpdateTime + MIN_UPDATE_INTERVAL) {
            uint256 currentSharePrice = _getCurrentSharePrice();
            
            if (lastUpdateTime > 0 && lastSharePrice > 0 && currentSharePrice > lastSharePrice) {
                uint256 timeElapsed = block.timestamp - lastUpdateTime;
                uint256 priceChangeRatio = ((currentSharePrice - lastSharePrice) * APY_PRECISION * 1e18) / lastSharePrice;
                calculatedAPY = (priceChangeRatio * 365 days) / (timeElapsed * 1e18);
            }
            
            lastSharePrice = currentSharePrice;
            lastUpdateTime = block.timestamp;
            
            emit MetricsUpdated(msg.sender, calculatedAPY, currentSharePrice);
        }
        _;
    }
}"
    },
    "lib/forge-std/src/interfaces/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity >=0.6.2;

/// @dev Interface of the ERC20 standard as defined in the EIP.
/// @dev This includes the optional name, symbol, and decimals metadata.
interface IERC20 {
    /// @dev Emitted when `value` tokens are moved from one account (`from`) to another (`to`).
    event Transfer(address indexed from, address indexed to, uint256 value);

    /// @dev Emitted when the allowance of a `spender` for an `owner` is set, where `value`
    /// is the new allowance.
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /// @notice Returns the amount of tokens in existence.
    function totalSupply() external view returns (uint256);

    /// @notice Returns the amount of tokens owned by `account`.
    function balanceOf(address account) external view returns (uint256);

    /// @notice Moves `amount` tokens from the caller's account to `to`.
    function transfer(address to, uint256 amount) external returns (bool);

    /// @notice Returns the remaining number of tokens that `spender` is allowed
    /// to spend on behalf of `owner`
    function allowance(address owner, address spender) external view returns (uint256);

    /// @notice Sets `amount` as the allowance of `spender` over the caller's tokens.
    /// @dev Be aware of front-running risks: https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    function approve(address spender, uint256 amount) external returns (bool);

    /// @notice Moves `amount` tokens from `from` to `to` using the allowance mechanism.
    /// `amount` is then deducted from the caller's allowance.
    function transferFrom(address from, address to, uint256 amount) external returns (bool);

    /// @notice Returns the name of the token.
    function name() external view returns (string memory);

    /// @notice Returns the symbol of the token.
    function symbol() external view returns (string memory);

    /// @notice Returns the decimals places of the token.
    function decimals() external view returns (uint8);
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/extensions/IERC20Metadata.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
"
    },
    "src/interfaces/IStrategyAdapter.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

interface IStrategyAdapter {
    function deposit(uint256 amount) external returns (uint256 shares);
    
    function withdraw(uint256 amount) external returns (uint256 withdrawn);
    
    function balanceOf(address account) external view returns (uint256);
    
    function getCurrentAPY() external view returns (uint256);
    
    // APY tracking functions
    function updateMetrics() external;
    
    function getLastUpdateTime() external view returns (uint256);
    
    function isAPYStale() external view returns (bool);
}"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC1363.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";
"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;

import {IERC165} from "../utils/introspection/IERC165.sol";
"
    },
    "lib/openzeppelin-contracts/contracts/utils/introspection/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"
    }
  },
  "settings": {
    "remappings": [
      "forge-std/=lib/forge-std/src/",
      "@openzeppelin/=lib/openzeppelin-contracts/",
      "@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
      "erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
      "halmos-cheatcodes/=lib/openzeppelin-contracts/lib/halmos-cheatcodes/src/",
      "openzeppelin-contracts/=lib/openzeppelin-contracts/"
    ],
    "optimizer": {
      "enabled": true,
      "runs": 400
    },
    "metadata": {
      "useLiteralContent": false,
      "bytecodeHash": "ipfs",
      "appendCBOR": true
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "evmVersion": "cancun",
    "viaIR": true
  }
}}